Presentació
Llistat de la macro "DAU_CONS".
Descripció: menú pral. i crit. gen. DAU
1 {alternar}
2 {ASIGNAR}V0~{VAR 0}~
3 {ASIGNAR}V1~{VAR 1}~
4 {ASIGNAR}V2~{VAR 2}~
5 {ASIGNAR}V3~{VAR 3}~
6 {ASIGNAR}V4~{VAR 4}~
7 {ASIGNAR}V5~{VAR 5}~
8 {ASIGNAR}V6~{VAR 6}~
9 {ASIGNAR}V7~{VAR 7}~
10 {ASIGNAR}V8~{VAR 8}~
11 {ASIGNAR}V9~{VAR 9}~
12
13 {ANIDAR}{VARIABLE}viaMacros~Dau_ctrl~
14 {SI SE CANCELA}{IR}Inici~~
15
16 {ROTULO}Inici~
17 {ASIGNAR}VG-menú~global~
18 {;}Per a qualsevol valor torna al Global consulta~
19 {ANIDAR}{VARIABLE}viaMacros~Dau_mnuC~
20
21 {CAR}1~~
22 {MIENTRAS}"{VAR 1}"!="0"~
23 {SI}"{VAR 1}">"0"&"{VAR 1}"<"4"~
24 {ANIDAR}{VARIABLE}viaMacros~Dau{VAR 1}~
25 {SI}"{VARIABLE}VG-llegir~"="sí"~
26 {ASIGNAR}0~{VARIABLE}viaDocs~DAU_{VAR 1}{VAR 2}{VAR 3}.w51~
27 {SI}"{VAR 1}"="3"~
28 {ANIDAR}{VARIABLE}viaMacros~DauLect~
29 {DE OTRO MODO}
30 {ANIDAR}{VARIABLE}viaMacros~Dau_lect~
31 {FIN SI}
32 {FIN SI}
33 {DE OTRO MODO}
34 {CAMPANA} {;}si ha premut qualsevol altra tecla~
35 {FIN SI}
36 {SI}"{VARIABLE}VG-menú~"="global"~
37 {ANIDAR}{VARIABLE}viaMacros~dau_mnuC~
38 {CAR}1~~
39 {FIN SI}
40 {FIN MIENTRAS}
41
42 {DES VISUALIZ.}
43 {ASIGNAR}0~{VARIABLE}V0~~
44 {ASIGNAR}1~{VARIABLE}V1~~
45 {ASIGNAR}2~{VARIABLE}V2~~
46 {ASIGNAR}3~{VARIABLE}V3~~
47 {ASIGNAR}4~{VARIABLE}V4~~
48 {ASIGNAR}5~{VARIABLE}V5~~
49 {ASIGNAR}6~{VARIABLE}V6~~
50 {ASIGNAR}7~{VARIABLE}V7~~
51 {ASIGNAR}8~{VARIABLE}V8~~
52 {ASIGNAR}9~{VARIABLE}V9~~
53
54 {sortir}NN
55 {alternar}
Comentaris
Macro cridada des de la macro DAU_TEXT.WPM
1. {alternar} canvia de document de WordPerfect.
2. a 11. {ASIGNAR} assigna a les variables de la "V0" a la "V9" el
valor que tenien les variables de la "0" a la "9". És per
aprofitar els valors que havien pres aquestes variables, però
donat-los uns altres noms perquè no interfereixin els nous
valors que ara els poguem assignar. Abans d'abandonar el menú
d'ajut, tornarem a recuperar el valor que tenien aquestes
macros, perquè la generació de documents continuï sense
problemes (línies 43. a 52.)
13. transfereix l'execució a la macro DAU_CTRL.WPM, que controla les
àrees lliures de treball.
14. {SI SE CANCELA} si apretem la tecla de cancel.lar (F1),
tranfereix l'execució al rètol "inici".
16. {ROTULO} declara el rètol "inici".
17. {ASIGNAR} assigna a la variable "VG-menú" el valor "global", que
més endavant farà que per a qualsevol valor tornem al menú de
consulta.
19. {ANIDAR} transfereix l'execució a la macro DAU_MNUC.WPM, que
presenta el menú de consulta.
21. {CAR}1 genera la variable 1, que segons el valor que li donem
ens adreçarà a diferents macros.
22. {MIENTRAS} mentre la variable "1" tingui un valor diferent de
"0"...
23. ... {SI} és més gran que "0" i més petit que "4" (entre 1 i
3)...
24. ... transfereix l'execució a la macro DAUx.WPM, on "x" pot
prendre els valors "1", "2" i "3", que ens adreçarà als 3 menús
possibles de consulta.
25. {ASIGNAR} assignarem a la variable "0" el valor
"c:\{dau}.slc\docs\dau_xxx.w51", on "xxx" correspon al valor de
les opcions del menú que haguem triat, contingudes a les
variables {VAR 1}, {VAR 2} i {VAR 3}. Així, la {VAR 0} tindrà el
valor del document que se'ns obrirà segons l'opció que haguem
triat.
27. {SI} la variable "1" té el valor "3"...
28. transfereix l'execució a la macro DAULECT.WPM, que presenta un
fitxer sota control.
29. {DE OTRO MODO} mentre que si no és igual a 3...
30. ... transfereix l'execució a la macro DAU_LECT.WPM, que presenta
també un fitxer sota control, com DAULECT.WPM, però amb unes
altres opcions de moviment per pantalla.
33. {DE OTRO MODO} si hem premut una tecla altra que 0-1-2-3...
34. {CAMPANA} sona un xiulet de l'ordinador
36. {SI} si el valor de la variable "VG-menú" és "global"...
37. transfereix l'execució a la macro DAU_MNUC.WPM, que presenta el
menú de consulta i
38. torna a activar la variable "1", creant un bucle). Només
sortirem d'aquest menú de consulta amb l'opció "0" marcada al
menú.
43. a 52. torna a assignar els valors que tenien les variables de
"0" a "9" abans d'entrar al menú de consulta, que havíem guardat
a les variables de "V0" a "V9".
54. "{sortir}NN" neteja pantalla.
55. {alternar} canvia de document i retorna el control al punt de
generació de documents on ens trobàvem abans d'accedir al menú
d'ajuda.
Josep Tordera, Lluís de Yzaguirre i Víctor Pàmies
Institut de Lingüística Aplicada (
Universitat "Pompeu Fabra")
Servei de Llengua Catalana (
Universitat de Barcelona)
corr-el: lluis punt deyzaguirre arrova upf punt edu