Presentació
Llistat de la macro "DAUPREAR".
Descripció: crea llista assistents reunió
1 {;}Entrada: paràmetres VP-pre i VP-post
2 Sortida: VP-pre+preposició+article+VP-post~
3
4 {;}AC:Si es cancel.la~
5 {SI SE CANCELA}{IR}Fugida~~
6
7 {;}A:Presentar les opcions possibles de "preposició+article~
8 {AVISO}{^P}{NAT}1~{NAT}1~{^Q}{esborra fins a fi de pàgina}
9 {^P}{NAT}1~{NAT}2~[06]
10 {^P}{NAT}4~{NAT}3~
11 Com cal substituir l'asterisc perquè la frase sigui correcta?
12 {^P}{NAT}4~{NAT}5~{^R}{VARIABLE}VP-pre~ * {VARIABLE}VP-post~.{^S}
13 {^P}{NAT}8~{NAT}8~{^]}1.{^\} "de l'" :
14 {^P}{NAT}24~{NAT}8~{VARIABLE}VP-pre~ de l'{VARIABLE}VP-post~
15 {^P}{NAT}8~{NAT}10~{^]}2.{^\} "del" :
16 {^P}{NAT}24~{NAT}10~{VARIABLE}VP-pre~ del {VARIABLE}VP-post~
17 {^P}{NAT}8~{NAT}12~{^]}3.{^\} "dels" :
18 {^P}{NAT}24~{NAT}12~{VARIABLE}VP-pre~ dels {VARIABLE}VP-post~
19 {^P}{NAT}8~{NAT}14~{^]}4.{^\} "de la" :
20 {^P}{NAT}24~{NAT}14~{VARIABLE}VP-pre~ de la {VARIABLE}VP-post~
21 {^P}{NAT}8~{NAT}16~{^]}5.{^\} "de les":
22 {^P}{NAT}24~{NAT}16~{VARIABLE}VP-pre~ de les {VARIABLE}VP-post~
23 {^P}{NAT}4~{NAT}19~Trieu una opció (1, 2, 3, 4, 5) >>>
24 ~
25
26 {;}A:Triar una opció de preposició+article~
27 {CAR}núm~~
28 {MIENTRAS}"{VARIABLE}núm~">"5"|"{VARIABLE}núm~"<"1"~
29 {CAMPANA}
30 {CAR}núm~~
31 {FIN MIENTRAS}
32
33 {IR}PrepArt{VARIABLE}núm~~
34
35 {ROTULO}PrepArt1~
36 {ASIGNAR}V-in~ de l'~
37 {IR}Final~
38
39 {ROTULO}PrepArt2~
40 {ASIGNAR}V-in~ del ~
41 {IR}final~
42
43 {ROTULO}PrepArt3~
44 {ASIGNAR}V-in~ dels ~
45 {IR}final~
46
47 {ROTULO}PrepArt4~
48 {ASIGNAR}V-in~ de la ~
49 {IR}final~
50
51 {ROTULO}PrepArt5~
52 {ASIGNAR}V-in~ de les ~
53
54 {;}A:Uneix les parts amb preposició i article~
55 {ROTULO}Final~
56 {VARIABLE}VP-pre~{VARIABLE}V-in~{VARIABLE}VP-post~
57 {REGRESAR}
58
59
60 {;}AC:Si es cancel.la~
61 {ROTULO}Fugida~
62 {ANIDAR}{VARIABLE}viaMacros~DauCance~
Comentaris
Macro cridada des de la macro DAULLIST.WPM.
1. {;} comentari de l'autor on ens explica que aquesta macro
parteix de les informacions recollides a les variables "VP-pre"
i "VP-post", entre les quals intercala la combinació de
preposició i l'article correcta.
5. {SI SE CANCELA}{IR} redirecciona la funció de la tecla de
cancel.lació cap el rètol "Fugida", que transfereix l'execució
a la macro DAUCANCE.WPM, que cancel.la el procediment i torna a
la macro matriu d'on parteix aquesta.
8. {AVISO} presenta en pantalla les opcions possibles de combinació
de preposició i article.
El comandament {esborra fins a fi de pàgina} ens neteja la
pantalla i {^Q} ens desactiva tots els atributs que hi poguessin
haver actius.
27. {CAR}núm genera la variable "núm", que contindrà el valor de
l'opció triada per l'usuari.
28. {MIENTRAS} mentre la variable "núm" sigui més gran que "5" o més
petita que "1" (o sigui, que no correspongui a cap de les
opcions del menú desplegat)...
29. ...{CAMPANA} sona el xiulet de l'ordinador i...
30. ...ens torna a presentar l'opció de triar una opció (crea un
bucle)
33. {IR}PrepArt{VARIABLE}núm~~ direcciona l'acció de la macro cap a
cada un dels 5 possibles rètols diferents, segons l'opció triada
al menú.
35. {ROTULO}PrepArt1 declara en rètol.
36. {ASIGNAR} assigna a la variable "V-in" el valor " de l'".
37. {IR} transfereix l'execució al rètol "final", que fa la
composició de les diferents variables que formen el nom complet
de l'òrgan que es reuneix.
39. {ROTULO}PrepArt2 declara en rètol.
40. {ASIGNAR} assigna a la variable "V-in" el valor " del ".
41. {IR} transfereix l'execució al rètol "final"
43. {ROTULO}PrepArt3 declara en rètol.
44. {ASIGNAR} assigna a la variable "V-in" el valor " dels ".
45. {IR} transfereix l'execució al rètol "final"
47. {ROTULO}PrepArt4 declara en rètol.
48. {ASIGNAR} assigna a la variable "V-in" el valor " de la ".
49. {IR} transfereix l'execució al rètol "final"
51. {ROTULO}PrepArt5 declara en rètol.
52. {ASIGNAR} assigna a la variable "V-in" el valor " de les ".
53. {IR} transfereix l'execució al rètol "final"
55. {ROTULO} declara el rètol "Final".
56. Ajunta i escriu la variable generada, intercalada entre les dues
que ja havíem generat abans.
57. {REGRESAR} retorna el control a la macro jeràrquicament superior
a aquesta.
61. {ROTULO} declara el rètol "Fugida".
62. {ANIDAR} transfereix l'execució a la macro DAUCANCE.WPM, que
cancel.la el document generat i inicialitza les variables
generals.
Josep Tordera, Lluís de Yzaguirre i Víctor Pàmies
Institut de Lingüística Aplicada (
Universitat "Pompeu Fabra")
Servei de Llengua Catalana (
Universitat de Barcelona)
corr-el: lluis punt deyzaguirre arrova upf punt edu