Presentació
Llistat de la macro "DAULLIST".
Descripció: crea llista assistents reunió
1 {DES VISUALIZ.}
2 {;}AC:Si es cancel.la~
3 {SI SE CANCELA}{REGR./CANCELAR}~{sortir}NN
4 {ACT VISUALIZ.}
5
6 {;}A:Demanar nom del departament, etc.~
7
8 {;}Inicialitzem els paràmetres de DAU_TEXT.~
9 {ASIGNAR}VP-missatge~Nom de l'organisme que es reuneix~
10 {ASIGNAR}VP-resposta~~
11 {ASIGNAR}VP-obliga~sí~
12 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
13
14 {;}A:Donar la prep. i l'article~
15 {ASIGNAR}VP-pre~Reunió~
16 {ASIGNAR}VP-post~{VARIABLE}VP-resposta~~
17 {ANIDAR}{VARIABLE}viaMacros~DauPreAr~
18 {Ir a}{esquerra}{esborra paraula}{Fin}{retorn}
19
20 {;}A:Donar lloc habitual de les reunions~
21 {ACT VISUALIZ.}
22
23 {;}Inicialitzem els paràmetres de DAU_TEXT.~
24 {ASIGNAR}VP-missatge~Lloc habitual de les reunions~
25 {ASIGNAR}VP-resposta~~
26 {ASIGNAR}VP-obliga~sí~
27 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
28 {VARIABLE}VP-resposta~{retorn}
29
30 {;}A:Donar nom i sexe del president~
31 {;}Inicialitzem els paràmetres de DAU_TEXT.~
32 {ASIGNAR}VP-missatge~Nom i cognoms de qui presideix la reunió~
33 {ASIGNAR}VP-resposta~~
34 {ASIGNAR}VP-obliga~sí~
35 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
36 {VARIABLE}VP-resposta~
37
38 {ASIGNAR}VP-qui~{VARIABLE}VP-resposta~~
39 {ANIDAR}{VARIABLE}viaMacros~DauSexe~
40 ,{VARIABLE}VP-sexe~{retorn}
41
42 {;}A:Donar nom i sexe del secretari~
43
44 {;}Inicialitzem els paràmetres de DAU_TEXT.~
45 {ASIGNAR}VP-qui~El/la secretari/ària~
46 {ANIDAR}{VARIABLE}viaMacros~DauSexe~
47 ,{VARIABLE}VP-sexe~{inici}{esquerra}
48
49 {SI}"{VARIABLE}VP-sexe~"="home"~
50 {ASIGNAR}secre~l secretari~
51 {DE OTRO MODO}
52 {ASIGNAR}secre~ la secretària~
53 {FIN SI}
54
55 {;}Inicialitzem els paràmetres de DAU_TEXT.~
56 {ASIGNAR}VP-missatge~Nom i cognoms de{VARIABLE}secre~~
57 {ASIGNAR}VP-resposta~~
58 {ASIGNAR}VP-obliga~sí~
59 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
60 {VARIABLE}VP-resposta~{Fin}{retorn}
61
62 {;}A:Entrar els noms dels assistents~
63
64 {;}Inicialitzem els paràmetres de DAU_TEXT.~
65 {ASIGNAR}VP-missatge~Nom i cognoms de l'assistent següent o "fi"~
66 {ASIGNAR}VP-resposta~~
67 {ASIGNAR}VP-obliga~sí~
68 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
69
70 {MIENTRAS}"{VARIABLE}VP-resposta~"!="fi"~
71 {VARIABLE}VP-resposta~{retorn}
72 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
73 {FIN MIENTRAS}
74
75 {;}A:Salvar el fitxer d'assistents~
76 {ROTULO}Salvament~
77 {;}Inicialitzem els paràmetres de DAU_TEXT.~
78 {ASIGNAR}VP-missatge~Nom d'aquest fitxer d'assistents~
79 {ASIGNAR}VP-resposta~~
80 {ASIGNAR}VP-obliga~sí~
81 {ANIDAR}{VARIABLE}viaMacros~Dau_text~
82 {salvar}{VARIABLE}viaDossier~{VARIABLE}VP-resposta~{retorn}
83 {ASIGNAR}VP-nomFitxer~{VARIABLE}VP-resposta~~
84
85 {SI}{ESTADO}&1024~ {;}el fitxer ja existia~
86 N{cancel lar}
87 {AVISO}Tria un altre nom de fitxer~
88 {ESPERAR}15~
89 {IR}Salvament~
90 {FIN SI}
91
92
93 {ANIDAR}{VARIABLE}viaMacros~Dau_i001~
94 {sortir}NN
Comentaris
Macro cridada des de la macro DAU_ARCR.WPM.
1. {DES VISUALIZ.} desactiva la visualització en pantalla (buida la
pantalla)
2. {;} comentari de l'autor del programa per indicar-nos cada part
de la macro de quina acció s'encarrega. Si després del signe de
comentari hi ha una "A", vol dir que només afecta l'acta de
reunió; si hi ha una "AC" vol dir que afecta l'acta i la
convocatòria de reunió i si hi ha una "C" vol dir que sols
afecta la convocatòria.
3. {SI SE CANCELA} si apretem la tecla de cancel.lar (F1), acaba
l'execució del programa, sense sortir de WordPerfect. A tots els
efectes, cancel.la el programa, no arxiva cap document i deixa
la pantalla en blanc.
Assigna aquest valor a {REGR./CANCELAR}, que serà la acció per
defecte des d'aquest punt del programa per a l'acció de
cancel.lar.
4. {ACT VISUALIZ.} activa la visualització en pantalla amb la
pantalla neta (perquè abans hem executat el comandament {DES
VISUALIZ.}
8. {;} comentari que ens avisa del caràcter especial de la macro
DAU_TEXT, ja que canviant el valor de les variables ens
qüestiona sobre els valors dels diferents paràmetres que hem
d'omplir per completar l'acta de reunió.
9. {ASIGNAR} assigna a la variable "VP-missatge" el valor
"Nom de l'organisme que es reuneix".
10. inicialitza la variable "VP-resposta".
11. {ASIGNAR} assigna a la variable "VP-obliga" el valor "sí".
12. {ANIDAR} transfereix l'execució a la macro DAU_TEXT.WPM, que
controla el valor de les variables de la llista d'assistents a
la reunió.
15. {ASIGNAR} assigna a la variable "VP-pre" el valor "Reunió".
16. {ASIGNAR} assigna a la variable "VP-post" el valor de la
variable "VP-resposta", que haurem omplert sota el control de la
macro DAU_TEXT.
17. {ANIDAR} transfereix l'execució a la macro DAUPREAR.WPM, que
controla i assigna la combinació preposició+article correcta per
a la convocatòria de reunió.
18. Esborra la primera paraula ("Reunió") de la línia que es veu en
vídeo invers, generada amb les variables encadenades que haurem
triat a mida que anàvem responent les qüestions de les macros
DAU_TEXT.WPM i DUAPREAR.WPM.
24. {ASIGNAR} assigna a la variable "VP-missatge" el valor
"Lloc habitual de les reunions".
Com podem veure, la macro DAU_TEXT.WPM ens serveix per omplir
diferents camps només canviant el valor de la variable que
enclou la pregunta que ens fa, com seguirem observant a
continuació.
25. inicialitza la variable "VP-resposta".
26. {ASIGNAR} assigna a la variable "VP-obliga" el valor "sí"
27. {ANIDAR} transfereix l'execució a la macro DAU_TEXT.WPM, que
controla el valor de les variables del lloc habitual de la
reunió.
28. Escriu en pantalla, en una segona línia, el valor de la variable
"VP-RESPOSTA", que haurem assignat a través de la macro
DAU_TEXT.WPM i a continuació hi afegeix un salt de línia
({Retorn}).
32. a 36. ens demana el nom i cognoms de qui presideix la reunió,
també a través de DAU_TEXT.WPM.
38. {ASIGNAR} assigna a la variable "VP-qui" el valor de la variable
"VP-resposta".
39. {ANIDAR} transfereix l'execució a la macro DAUSEXE.WPM, que
demana el sexe dels assistents a la reunió.
40. escriu a continuació del nom i cognoms del president de la
reunió "," i si és "home" o "dona" i fa un salt de línia.
45. a 47. ens demana el sexe del/de la secretari/ària, ho escriu i
retorna el cursor a l'inici de la línia.
49. a 53. a través de la informació que hem emmagatzemat a la
variable "VP-sexe" assigna el valor d'home o dona a la variable
"secre", que a continuació utilitzarem per demanar el nom del/de
la secretari/ària de la reunió.
56. a 60. ens demana el nom i cognoms del/de la secretari/ària de la
reunió i ho escriu, va a final de línia i fa un salt de línia.
64. a 68. ens demana el nom de la resta d'assistents a través de la
macro DAU_TEXT.WPM també, fins que nosaltres li marquem "fi".
70. {MIENTRAS} mentre el valor de la variable VP-resposta" sigui
diferent de "fi", ens segueix demanant més assistents.
76. {ROTULO} declara el rètol "Salvament".
78. a 82. guarda aquest fitxer d'assistents al nom que li indiquem
al programa a través de la macro DAU_TEXT.WPM, a través de
l'ordre {salvar}.
Com podem veure ho guarda en el directori marcat a la variable
"viaDossier"
83. {ASIGNAR} assigna a la variable "nomFitxer" el valor de la
variable "VP-resposta", que serà el nom que li haurem donat al
fitxer.
85. {SI} {ESTADO}&1024. Aquest comandament ens indica l'estat
operatiu de WordPerfect, que en aquest cas ens avisa que hem de
respondre a una pregunta d'opció "sí/no" del programa, perquè
aquest fitxer ja existia.
86. Dóna com a resposta a la pregunta anterior "N", perquè no
sobreescrigui el fitxer i cancel.la aquesta acció.
87. Apareix en pantalla un avís perquè triem un altre nom de fitxer.
88. {ESPERAR}15, deté l'acció de la macro durant un segon i mig
(compta en dècimes de segon) i torna a activar el rètol
"Salvament" que ens demanarà un nom pel fitxer d'assistents.
89. {FIN SI} acaba la subrutina iniciada a la línia 85 i que
controla que donem un nom no existent al fitxer d'assistents
93. {ANIDAR} transfereix l'execució a la macro DAU_I001.WPM, que ens
avisa que el fitxer guardat ens pot servir en futures sessions
per a reunions del mateix organisme, sense que haguem de tornar
a entrar totes les dades.
Josep Tordera, Lluís de Yzaguirre i Víctor Pàmies
Institut de Lingüística Aplicada (
Universitat "Pompeu Fabra")
Servei de Llengua Catalana (
Universitat de Barcelona)
corr-el: lluis punt deyzaguirre arrova upf punt edu